lördag, mars 08, 2008

Programmerare utan gränser

På jobbet har en "studiecirkel" med det smålustiga namnet Programmerare utan gränser startats. Lite då och då får de som är med en uppgift att lösa; man får lösa den hur man vill (så länge det blir rätt :)) och i vilket språk som helst. Jag är självklart en av de gränslösa programmerarna!

Den första uppgiften var att översätta tal till ord, exempelvis "432" blir "fyrahundratrettiotvå". Programmet ska klara av alla tal mellan 0 och 10^12. Vilket programmeringspråk passar bäst för detta? Commodore 64 BASIC v2 så klart! 38911 basic bytes of freedom!

Min lösning är som följer:
  1. Lagra talet som ska "ordifieras" i NUMBER$
  2. Splitta NUMBER$ i grupper om tre, exempel "1" -> [1], "1234" -> [1, 234], "1000100" -> [1, 0, 100]
  3. Ordifiera varje sådan grupp.
  4. Konkatenera grupperna (med rätt suffix, exempelvis "miljoner", "tusen").
  5. Siste men inte minst hanteras jobbiga specialfall genom att byta ut en substräng mot en annan.
Punkt 5 ovan kan behöva lite mer förklaring. Algoritmen 1-4 ger strängar i stil med "etttusen", "ettmiljoner", etc, vilket självklart inte är rätt. Det är dock bara några få specialfall att hantera så det är lätt att helt enklet söka igenom strängen man fått från steg 4 och ersätta det som är fel med det som det borde vara. Exempel: "ettmijljoneretttusenett" blir "enmiljonettusenett".

För den som är väldigt nyfiken så följer källkoden här:

100 REM set test=0 if you don't want the test to be run (test=1 otherwise)
110 TEST=0
200 REM read data for 0-19 into t019$()
210 GOSUB 10000
220 REM read data for tens (0-90) into ttens$()
230 GOSUB 10100
240 REM read data for 1000, miljon, etc
250 GOSUB 10200
300 REM test method 'split'
310 IF TEST=1 THEN GOSUB 1100
320 REM test method 'wordify0to999'
330 IF TEST=1 THEN GOSUB 2200
340 REM test method 'wordifyall'
350 IF TEST=1 THEN GOSUB 3500
360 REM test method 'replace'
370 IF TEST=1 THEN GOSUB 6000
380 REM test method 'main'
390 IF TEST=1 THEN GOSUB 8000
900 REM the actual program starts here
910 TEST=0
920 PRINT "ange tal" : INPUT NUMBER$
930 GOSUB 7000
940 PRINT M$
999 END
1000 REM ------ method 'split' ------
1003 REM splits a string in groups of thee. example: "9876542" -> [9, 876, 542]
1005 REM in: number$, out: groups(), ngrp
1010 IF TEST=1 THEN PRINT " test: splitting <"+NUMBER$+">."
1020 DEF FN MOD3(X)=X-INT(X/3)*3
1030 IF FNMOD3(LEN(NUMBER$))=0 THEN 1050
1040 NUMBER$="0"+NUMBER$ : GOTO 1030
1050 FOR I = 1 TO LEN(NUMBER$) STEP 3
1060 : GROUPS(INT(I/3))=VAL(MID$(NUMBER$, I, 3))
1070 NEXT I
1080 NGRP=INT(I/3)-1
1090 RETURN
1100 REM - test case for method 'split'
1110 NUMBER$="2" : GOSUB 1000
1120 IF GROUPS(0) <> 2 GOTO 30000
1130 IF NGRP <> 0 GOTO 30000
1140 NUMBER$="19" : GOSUB 1000
1150 IF GROUPS(0) <> 19 GOTO 30000
1160 IF NGRP <> 0 GOTO 30000
1170 NUMBER$="123" : GOSUB 1000
1180 IF GROUP(0) <> 123 GOTO 30000
1190 IF NGRP <> 0 GOTO 30000
1200 NUMBER$="54321" : GOSUB 1000
1210 IF GROUP(0) <> 54 GOTO 30000
1220 IF GROUP(1) <> 321 GOTO 30000
1230 IF NGRP <> 1 GOTO 30000
1240 NUMBER$="1234" :GOSUB 1000
1250 IF GROUP(0) <> 1 GOTO 30000
1260 IF GROUP(1) <> 234 GOTO 30000
1270 IF NGRP <> 1 GOTO 30000
1280 NUMBER$="9876543210" :GOSUB 1000
1290 IF GROUP(0) <> 9 GOTO 3000000
1300 IF GROUP(1) <> 876 GOTO 30000
1310 IF GROUP(2) <> 543 GOTO 30000
1320 IF GROUP(3) <> 210 GOTO 30000
1330 IF NGRP <> 3 GOTO 30000
1340 RETURN
2000 REM --- method 'wordify0to999' ---
2010 REM in: wo, out: wrd$
2020 REM example: 99 -> nitionio
2030 IF TEST=1 THEN PRINT " test: wordifying <" + STR$(WO) + ">."
2040 DEF FN FRST(X)=X-INT(X/10)*10
2050 DEF FN SCND(Y)=INT(Y/10)-FNTHRD(Y)*10
2055 DEF FN THRD(Z)=INT(Z/100)
2060 DEF FN THRD(Z)=INT(Z/100)
2070 WRD$=""
2080 IF WO <= 19 THEN WRD$=T019$(WO):RETURN 2090 IF FNSCND(WO) > 0 THEN WRD$=TTENS$(FNSCND(WO))
2100 IF FNFRST(WO) > 0 THEN WRD$=WRD$+T019$(FNFRST(WO))
2110 IF FNTHRD(WO) > 0 THEN WRD$=T019$(FNTHRD(WO))+"hundra"+WRD$
2190 RETURN
2200 REM - test method 'wordify0to99' -
2210 WO=9 : GOSUB 2000
2220 IF WRD$ <> "nio" GOTO 30000
2230 WO=19 : GOSUB 2000
2240 IF WRD$ <> "nitton" GOTO 30000
2250 WO=20 : GOSUB 2000
2260 IF WRD$ <> "tjugo" GOTO 30000
2270 WO=90 : GOSUB 2000
2280 IF WRD$ <> "nittio" GOTO 30000
2290 WO=21 : GOSUB 2000
2300 IF WRD$ <> "tjugoett" GOTO 30000
2310 WO=0 : GOSUB 2000
2320 IF WRD$ <> "noll" GOTO 30000
2330 WO=55 : GOSUB 2000
2340 IF WRD$ <> "femtiofem" GOTO 3000
2350 WO=999 : GOSUB 2000
2360 IF WRD$ <> "niohundranittionio" GOTO 30000
2370 WO=101 : GOSUB 2000
2380 IF WRD$<> "etthundraett" GOTO 30000
2390 WO=500 : GOSUB 2000
2400 IF WRD$ <> "femhundra" GOTO 30000
2500 RETURN
3000 REM -- method 'wordifyall'
3010 REM in: groups(), ngrp, out: all$
3015 REM ngrp: max index of group()
3020 REM example: [9, 3] => "niotusentre"
3025 REM note: does not handle special cases, e.g., "ettusen" and "enmiljon"
3027 REM correctly. this is done later by a special "correction" function.
3030 IF TEST=1 THEN PRINT " test: wordifying all <" + STR$(GROUPS(0)) + "...>"
3050 ALL$=""
3080 FOR IDX=0 TO NGRP
3090 : GOSUB 4000
3200 : ALL$=ALL$+WRD$
3210 : IF WRD$ <>"" THEN ALL$=ALL$+TPOT$(NGRP-IDX)
3300 NEXT IDX
3400 RETURN
3500 REM test of method 'wordifyall'
3510 GROUPS(0)=90 : NGRP=0 : GOSUB 3000
3520 IF ALL$ <> "nittio" GOTO 30000
3530 GROUPS(0)=2 : GROUPS(1)=0 : NGRP=1 : GOSUB 3000
3540 IF ALL$ <> "tvatusen" GOTO 30000
3550 GROUPS(0)=9 : GROUPS(1)=51 : NGRP=1 : GOSUB 3000
3560 IF ALL$ <> "niotusenfemtioett" GOTO 30000
3570 GROUPS(0)=1 : GROUPS(1)=11 : GROUPS(2)=900 : NGRP=2 : GOSUB 3000
3580 IF ALL$ <> "ettmiljonerelvatusenniohundra" GOTO 3000
3590 GROUPS(0)=9 : GROUPS(1)=0 : GROUPS(2)=0 : NGRP=2 : GOSUB 3000
3600 IF ALL$ <> "niomiljoner" GOTO 30000
3610 GROUPS(0)=1 : GROUPS(1)=0 : NGRP=1 : GOSUB 3000
3620 IF ALL$ <> "etttusen" GOTO 30000
3630 GROUPS(0)=6 : GROUPS(1)=5 : GROUPS(2)=4 : GROUPS(3)=3 : GROUPS(4)=2: NGRP=4
3640 GOSUB 3000
3650 IF ALL$ <> "sexbiljonerfemmiljarderfyramiljonertretusentva" GOTO 30000
3700 RETURN
4000 REM method that works like 'wordify0to999' but returns "" instead of "noll"
4010 REM if it is a three-group > 1000.
4020 REM in: groups(), idx
4025 REM out: wrd$
4030 REM idx = index of group
4040 WO=GROUPS(IDX) : WRD$=""
4050 IF IDX=0 THEN GOSUB 2000 : RETURN
4060 IF WO > 0 THEN GOSUB 2000 : RETURN
4070 RETURN
5000 REM -- method 'replace'
5005 REM -- function that replaces a substing (s$) of another string (m$)
5010 REM -- with a replacement string (r$)
5020 REM -- returns: m$ - the modified string
5030 IF TEST=1 THEN PRINT " test: replace <"+S$+","+M$+","+R$+">"
5100 FOR SI=1 TO LEN(M$)-LEN(S$)+1
5120 : IF MID$(M$, SI, LEN(S$))=S$ THEN GOTO 5500
5130 NEXT SI
5140 RETURN
5500 REM replace mid$(m$, si, len(s$)) with r$
5510 M$=LEFT$(M$, SI-1) + R$ + MID$(M$, SI+LEN(S$), LEN(M$)-SI-LEN(S$)+1)
5520 RETURN
6000 REM test-case for method 'replace'
6010 M$="etttusen" : S$="ttt" : R$="tt" : GOSUB 5000
6020 IF M$ <> "ettusen" GOTO 30000
6030 M$="ettmiljonertio" : S$="ettmiljoner" : R$="enmiljon" : GOSUB 5000
6040 IF M$ <> "enmiljontio" GOTO 30000
6050 M$="elva" : S$="etttusen" : R$="ettusen" : GOSUB 5000
6060 IF M$ <> "elva" GOTO 30000
6070 M$="enmiljonetttusen" : S$="etttusen" : R$="ettusen" : GOSUB 5000
6080 IF M$ <> "enmiljonettusen" GOTO 30000
6500 RETURN
7000 REM -- the main function. argument number$ is wordified (returned in m$)
7010 IF TEST=1 THEN PRINT " test: main <"+NUMBER$+">"
7020 REM call 'split'. returns groups(), ngrp
7030 GOSUB 1000
7040 REM call 'wordify0tall". returns all$. arguments: groups(), ngrp
7050 GOSUB 3000
7060 REM handle special cases, e.g., "etttusen" should be "ettusen".
7070 REM this is done using the 'replace' function.
7080 REM arguments: m$, s$, r$. returns m$
7090 M$=ALL$ : S$="etttusen" : R$="ettusen" : GOSUB 5000
7100 S$="ettmiljoner" : R$="enmiljon" : GOSUB 5000
7110 S$="ettmiljarder" : R$="enmiljard" : GOSUB 5000
7120 S$="ettbiljoner" : R$="enbiljon" : GOSUB 5000
7500 RETURN
8000 REM test for the main function.
8010 NUMBER$="101" : GOSUB 7000
8020 IF M$ <> "etthundraett" GOTO 30000
8030 NUMBER$="1001001001000" : GOSUB 7000
8040 IF M$ <> "enbiljonenmiljardenmiljonettusen" GOTO 30000
8050 NUMBER$="2002002002000" : GOSUB 7000
8060 IF M$ <> "tvabiljonertvamiljardertvamiljonertvatusen" GOTO 30000
8999 RETURN
10000 REM read data for 0-19
10010 DIM T019$(19)
10020 FOR I=0 TO 19 : READ T019$(I)
10030 NEXT I
10040 RETURN
10100 REM read data fot 0, 10, 20, etc
10110 DIM TTENS$(9)
10120 FOR I=0 TO 9 : READ TTENS$(I)
10130 NEXT I
10140 RETURN
10200 REM read data for 1000, miljon...
10210 DIM TPOT$(4)
10220 FOR I=0 TO 4 : READ TPOT$(I)
10230 NEXT I
10240 RETURN
20000 REM -- data for t019$()
20010 DATA "noll", "ett", "tva", "tre", "fyra", "fem", "sex", "sju", "atta"
20020 DATA "nio", "tio", "elva", "tolv", "tretton", "fjorton", "femton"
20030 DATA "sexton", "sjutton", "arton", "nitton"
20100 REM -- data for ttens$()
20110 DATA "noll", "tio", "tjugo", "tretto", "fyrtio", "femtio", "sextion"
20120 DATA "sjutio", "attio", "nittio"
20200 REM -- data for 1000, miljon ...
20210 DATA "", "tusen", "miljoner", "miljarder", "biljoner"
29999 END
30000 PRINT "assertion error!"

Etiketter:

måndag, februari 18, 2008

Perioder

Jag är en periodare. Ibland gör jag inget annat än spelar in musik (som kanske märks här ibland) och ibland gör jag inget annat än ser på serier (The Next Generation, Battlestar Galactica, Lost, Heroes, mfl (ser ni något mönster förresten?)). Andra saker som jag haft perioder av är att se på film (sommaren 2005), generera dikter, programmera och tänka kring programmeringsspråk, spela gamla dator-/tv-spel, och spela nya dito. Senast i raden av perioder är att återigen att programmera.

Vi får väl se vad som händer med dessa de senaste programmeringsprojekten. De här hursomhelst mer praktiskt användbara än, exempelvis, ett diktgenereringsprogram. :) Diktgenereringsprogrammet har jag förresten inte arbetat på på säkert ett år, men idén lever ännu i mitt huvud i alla fall. Får se om om jag tar tag i det där igen, för det är en kul idé tycker jag.

Etiketter: , , ,

lördag, april 07, 2007

Filmtitelsundersökning på svenska

Samma undersökning som tidigare, men denna gång för svenska filmer. Det finns lite färre svenska filmer än engelska, därför presenterar jag inte en 10-i-topp- och en 10-i-botten-lista utan bara en enda lista med alla ord.

Glad påsk, förresten.

ord    betyg  antal
-----------------------
ett 6.5 12
liv 6.3 10
livet 6.0 10
barn 6.0 11
det 5.9 20
med 5.9 25
till 5.8 22
som 5.7 27
jag 5.7 27
och 5.6 89
den 5.5 24
the 5.5 13
min 5.4 11
lilla 4.4 11

Etiketter: , ,

onsdag, mars 14, 2007

Den 14 Mars...

...1768 föddes Jean Baptiste Joseph Fourier,
...1879 föddes Albert Einstein,
...1960 introducerades LISP, och
...1994 släpptes Linux kernel version 1.0.0.

Inte så illa för en lite dag som denna.

Etiketter: , ,

tisdag, januari 23, 2007

Filmtitelordsundersökning

I helgen gjorde jag en sökning på Filmtipset (som förövrigt erbjuder en väldigt bra tjänst) efter  filmer vars titel innehöll order incredible. Det slog mig då att väldigt många av filmerna hade fått dåliga betyg (betyg 1 eller 2 av 5). Jag bestämde mig då för att undersöka om det finns någon korrelation mellan vissa ord i en films titel och filmens betyg.

Sagt och gjort, jag började med att ladda ner IMDBs betygsdatabas och filtrerade ut de engelska filmerna. Jag valde de engelska filmerna av flera anledningar: dels för att att engelska filmer är de vanligasta hos oss i Sverige, dels för att minimera risken att ett ord betyder helt olika saker i olika språk (semantiska kollisioner*, om man vill vara lite fancy-mancy), men också för att det inte skulle bli alltför många ord och filmer att söka bland.

Sedan började jag skriva ett litet program som fann alla unika ord i filmtitlarna, och för varje ord fann alla filmer vars titel innhåller ordet. Medelbetyget räknades sedan ut för dessa filmer, vilket ger ordet ett medelbetyg. Slutligen sorteras orden i betygsordning.
Ord som förekommer sällan (jag valde färre än 10 gånger) sorteras bort för att undvika att att ord som förkommer i en enda superbra eller asdålig film ska förstöra min fina undersökning...

Vad var då resultatet? Ja, de filmer du inte ska hyra är de som innehåller något av följande ord:

ord         betyg antal
-----------------------
witchcraft   2.8   13
ranchman     3.0   13
gratitude    3.1   11
emmanuelle   3.2   12
hubby        3.2   14
wooing       3.4   14
joke         3.4   16
ninja        3.4   57
reformation  3.4   11
squaw        3.4   11
belmont      3.4   12
bikini       3.4   23
ike          3.5   20
jealousy     3.6   19
failed       3.6   10
burglar      3.6   42
vampires     3.6   10
broncho      3.6   128


Kolumnen antal är antalet filmer med motsvarande ord i titeln. De filmer du däremot ska se är de med förljande ord i titlen:

ord         betyg antal
-----------------------
sense        7.5   13
chan         7.4   28
bugs         7.4   30
concert      7.2   20
moments      7.2   13
documentary  7.1   20
hare         7.1   83
minds        7.1   14
jump         7.1   12
history      7.0   50
razor        7.0   10
speaking     7.0   10
daffy        7.0   33
language     7.0   10
alexander    7.0   10
start        7.0   10


*) Det där hittade jag bara på i skrivandets stund. Men, vem vet, det kanske kallas så på riktigt. :)

Etiketter: ,

måndag, oktober 30, 2006

Kompilator-HMI

Det bedrivs en hel del forskning rörande HMI (human-machine-interaction/interface) vars mål är att förenkla interaktionen mellan en krånlig och lynnig pjäs (datorn/maskinen) och en krånlig och lynning varelse (människan). Ett fält av HMI är datapresentation, dvs hur man ska presentera (textuellt, visuellt, etc) information så att en människa kan ta till sig det lätt, snabbt, exakt, osv.

Och nu till poängen -- idag på jobbet när jag skrev ett test fick jag följande felmeddelande av GCC:
SdtRcrTest.cc:264: error: no match for 'operator==' in '(*(eu->sgt::rcr::SdtRcr::_vptr.Object + 100u))(eu) == (*((*(((SdtRcrTest*)this)->SdtRcrTest::_cell[1]->sgt::rcr::RcrLeclInfo::_vptr.RcrLeclInfo + 24u))(((SdtRcrTest*)this)->SdtRcrTest::_cell[1])->sgt::rcr::SfInfo::_vptr.SfInfo + 8u))((*(((SdtRcrTest*)this)->SdtRcrTest::_cell[1]->sgt::rcr::RcrLeclInfo::_vptr.RcrLeclInfo + 24u))(((SdtRcrTest*)this)->SdtRcrTest::_cell[1]))'
Snacka om HMI! Trots att jag kan min både min kod och GCC ganska bra så säger det där felmedelandet mig inte ett smack (ok, det säger mig lite -- det verkar vara något med en metodpekare...). Det hade varit precis lika informativt om GCC istället sa:
SdtRcrTest.cc: ?SYNTAX ERROR.
Men jaja, det kanske finns någon här i världen som inte är lika krånlig och lynning som jag som förstår det där medelandet.
(Klassnamn etc i felmeddelandet har ändrats för att inte avslöja några eventuella hemligheter).

Etiketter: ,

torsdag, oktober 26, 2006

Brahetsmått

Jag har inte undersökt saken så noga, men jag är övertygad om att det finns diverse mått på hur bra ett programmeringsspråk är. En sak jag uppskattar är en enkel och konsistent syntax samt ett stort standardbibliotek med kraftfulla funktioner/klasser.

(defun has-consistent-syntax? (language)
(or (string-equal language "lisp")
(string-equal language "scheme")
)
)

bool SyntaxAnalyzer::
hasConsistentSyntax(std::String language) {
return !((language == "C++") || (language == "C"));
}


Ett annat mått på hur bra ett språk är är "'fuck's per source file", eller mer generellt "antal svordommar per källkodsfil" (nej, detta är inte ett seriöst mått, men likväl ett mått med viss mått av värde).

Google Code Search
är en söktjänst som ger möjlighet att söka i open source-källkod efter vad man nu önskar. Detta utnyttjades här för att uppskatta hur bra några vanliga språk är. (Notera speciellt andelen 'fuck' per källkodsfil som C har).

Etiketter: ,

onsdag, juli 27, 2005

Pseudokod

Jag gogglade på dilbert och stötte via lite omvägar på följande:
I suppose the sign of a sweet-spot language is when you naturally fall into using it for writing pseudocode.
Till det vill jag tillägga att jag idag skrev följande kodsnutt i C++:
for(list<pair<int, int> >::iterator iter = orderList.begin();
iter != orderList.end(); ++iter) {
/* Your fulkod here. */
}
Det är är väl närmast sour-spot, skulle jag tro...

Etiketter: ,

tisdag, mars 08, 2005

"Clever rhymes, see you later"

Sedan den senaste updateringen har diktprogrammet begåvats med ytterligare två egenskaper. Det kan nu uppskatta antalet stavelser i ord genom att räkna antalet sjok av vokaler (förutom om det är e i slutet av ett ord, exempelvis som i little). Några körexempel kan ses nedan.

> (num-of-syllables 'little)
1
> (num-of-syllables 'profoundly)
3
> (num-of-syllables 'supercalifragilisticexpialidocious)
13
>

Det verkar funka ganska hyfsat. Tanken är att jag ska kunna åstakomma lite rytm i dikterna genom att använda denna funktionen. Ännu används den inte, men funktionen finns och väntar bara på att avändas i diktgenereringen.

Vidare kan man nu filtrera ord-listan på ord som rimmar på ett specifikt ord. Här följer några exempel:

> (get-rhyming 'international *adj-db*)
(((chanceful) (mo 3 vi 6 si 4 co 4 hu 5 fu 6 te 6))
((glacial glacial) (fr -3 mo -3 vi -4 si 3 cr 2 co 4 hu 2 fu -3 te -7))
...
> (get-rhyming 'women *adj-db*)
(((barren) (fr -3 mo -4 vi -7 si 3 cr 5 co 4 hu 2 fu -5 te 3 ki -3))
((frozen) (fr -3 mo -3 vi -4 si 3 cr 2 co 4 hu 2 fu -3 te -7))
...
> (get-rhyming 'day *adj-db*)
(((chancy dicey dicey dodgy) (mo 3 vi 6 si 4 co 4 hu 5 fu 6 te 6))
((concisely briefly shortly) (fr -3 vi -3 si -5 cr -3 co 4 hu 2 fu -4 te -3 ki -5))
...
>

Som man kan se så fungerar funktionen hyfsat, men inte tipp-top. Men det beror på att mina rim-regler är ganska (läs: mycket) enkla. Jag tror dock inte att kan kommer göra rim-reglerna speciellt avancerade eftersom det blir troligvis för jobbigt. Men visst, jag kan göra dem bättre än vad de för tillfället är.

Etiketter:

söndag, februari 20, 2005

Say-what-you-say?

Första dikten komponerad av det nya diktprogrammet kan läsas nedan. Jag är inte helt säker, men jag tror att det mesta är gojja.

your sightly nimbus of crepuscularness
heartily approches my brackish banshee
and our christlikeness of fire
embrace us with the fairness of roughneck

Jag kanske ska korrigera några parametrar...

I mallen som används för att generera ovanstående dikt finns det fem luckor för slumpmässiga adjektiv, fyra för substantiv och ett för adverb (några verbluckor finns inte för jag har inte fixat till en vettig databas över verb ännu). I adjektiv-, adverb- och substantivdatabaserna finns det 1000, 200 respektive 300 ord. Detta ger att diktmallen som mest kan generera i storleksordnigen 103*5 * 2*102 * (3*102)4 =~ 1030.
För att inte dikterna ska bli helt uppåt väggarna har jag dock begränsat valen av ord som ska fylla luckorna genom att införa beroenden mellan dem. Alltså valet av det ord som ska stå i en viss lucka inte är oberoende av de ord som fyller övriga luckor. Jag gissar att en bättre uppskattning är 1010, men detta är bara en gissning. I vilket fallsomhelst så är det hisklig massa dikter man kan generera - bara att börja läsa!


Tillägg:
En närmare analys gav att 1010 är en ganska god uppskattning till antalet möjliga dikter.

Etiketter: ,

lördag, februari 19, 2005

Adjektiv sekunderar poesin på minuten

Jag har skrivit om en del (läs allt), i mitt poesi-program. Ännu är det inte i något fungeraden tillstånd, men det kan i alla fall ge mig några bra adjektiv, adverb, verb och substantiv om jag ber det snällt. Nedan är ett utklipp från en testkörning där programmet ger olika adjektiv beroende på vilka parametrar jag sätter. I exmplet anger jag bara två, men man kan ange fler om man vill.

Orden är graderade på olika skalor, så som friendship (fr), vividness (vi) och mood (mo). Vill man exempelvis ha ett väldigt ledset adjektiv anger man -10 i mood-parametern.


> (get-adj '(fr 9))
(affectionate caring fond lovesome tender warm loving)
> (get-adj '(fr 9 mo -4))
(alone lonesome alone lone lonely solitary)
> (get-adj '(fr -3 mo -4))
(bleached faded washed-out washy colourless weakened bare barren bleak desolate dim)
> (get-adj '(fr -3 vi -4))
(arctic freezing frigid gelid glacial icy polar frosty frozen glacial wintry cold)
> (get-adj '(mo -9 vi -9))
(dark aphotic black pitch-black pitch-dark caliginous crepuscular darkened darkening darkling dim subdued glooming gloomy gloomful lightless unilluminated unlighted unlit dusky tenebrous tenebrific tenebrious)
> (get-adj '(mo 9 vi -9))
(concisely briefly shortly |in brief| |in short|)
>

Jag antar att det inte krävs någon förklaring till vad detta ska användas till i ett poesigenereringsprogram... Som man kan se så funkar det inte perfekt på något sätt, men det jag tror nog det kan bli bra i slutändan.

Etiketter: ,

måndag, februari 14, 2005

Och nu över till samma sak igen

Som jag skrev i går så håller jag på med en litet dikt-program. Jag har utvecklat det lite idag, och det har fått större variation nu, men på bekostnad av grammatiska fel, osammanhängande rader etc.
Vissa dikter blir trots detta ganska hyfsade, dock är de bara två rader långa, men det hoppas jag kunna fixa till i framtiden. Nedan kan fyra av några (väl valda...) dikter som programmet gjort läsas. Jag gillar den sista mest.


how can a dead crow cry
in the nest of a frightened dove



the mist of dawn cover your night
but you are still dreaming



can the brave champion die
when heavy rain drops falls



when a dead tear dream
heavy rain drops falls



Alla fyra är direkt tagna från programmet utan att jag ändrat eller förbättrat på något sätt. Men som sagt, de är väl valda...

Etiketter: ,

söndag, februari 13, 2005

Och nu över till något helt annat

Jag halkade in på denna sidan när jag surfade för några dagar sedan. Jag tyckte att det var en ganska rolig idé och började fundera på att skriva ett sådant program själv. Idag började jag skriva programmet och några timmar senare spottade det ut sin första dikt:

when I am still asleep
sunlight embrace my skin
heavy smoke rise from the dove
embarressed by the light

Programmet är inte så himla avancerat egentligen, ett exempel förklara funktionen bäst. Jämför nedanstående rader med den första och tredje raden i dikten så förstår du hur enkelt programmet är.

when I am still ONE-OF(asleep, dreaming)
SYNONYM(dark) smoke rise from the ONE-FROM(nature)


Programmet består alltså av en mängd sådana rader, men också en synonym- och kategori-databas. Kategoridatabas är en databas över vilken typ ett ord är, ONE-FROM()-funktionen använder denna för att på rad tre få ett ord som ligger under kategorin nature Ovanstående kodrader kommer jag i forsättnigen kalla rad-mallar.

Änså länge är raderna helt oberoende, och det var bara slumpen som gjorde att dikten ovan blev relativt vettig. Jag har några idéer för hur man ska kunna få rader och verser att vara sammanhängande, men det är bara idéer ännu. Jag har även lite tankar om att försöka styra innehållet i vad programmet generar, exempelvis genom att man anger nyckelord som måste vara med eller något liknande. Jag kanske också försöker få raderna rimma, men det kräver nog en väldigt stor databas över ord och rad-mallar så det blir nog inte av.

Jag ska lägga till fler ord och rad-mallar och se hur pass bra variation man kan få på dikterna utan att de allra flesta blir helt värdelösa. Jag tror nämligen att ju större "frihet" man ger programmet desto ovanligare blir det med bra dikter.
Avslutningsvis citerar jag vad hade att säga om programmet dagens väder... :)

heavy snow falls
when winter ends

Etiketter: ,